Terraformを使ってAWS上にCOVID-19 追跡Web Appをデプロイしてみました

ec2.tf

# ====================
#
# AMI
#
# ====================

# 最新版のAmazonLinux2のAMI情報

data "aws_ami" "covid19" {
  most_recent = true
  owners      = ["amazon"]
  filter {
    name   = "architecture"
    values = ["x86_64"]
  }
  filter {
    name   = "root-device-type"
    values = ["ebs"]
  }
  filter {
    name   = "name"
    values = ["amzn2-ami-hvm-*"]
  }
  filter {
    name   = "virtualization-type"
    values = ["hvm"]
  }
  filter {
    name   = "block-device-mapping.volume-type"
    values = ["gp2"]
  }
  filter {
    name   = "state"
    values = ["available"]
  }
}

# ====================
#
# EC2 Instance
#
# ====================
resource "aws_instance" "covid19" {
  ami                    = data.aws_ami.covid19.image_id
  vpc_security_group_ids = [aws_security_group.covid19.id]
  subnet_id              = aws_subnet.covid19.id
  key_name               = aws_key_pair.covid19.id
  instance_type          = "t2.micro"
  tags = {
    Name = "covid19"
  }
}

# ====================
#
# Elastic IP
#
# ====================
resource "aws_eip" "covid19" {
  instance = aws_instance.covid19.id
  vpc      = true
}

# ====================
#
# Key Pair
#
# ====================
resource "aws_key_pair" "covid19" {
  key_name   = "covid19"
  public_key = file("./covid19.pub")
 # 先程`ssh-keygen`コマンドで作成した公開鍵を指定
}

vpc.tf

# ====================
#
# VPC
#
# ====================

resource "aws_vpc" "covid19" {
  cidr_block           = "10.0.0.0/16"
  enable_dns_support   = true # DNS解決を有効化
  enable_dns_hostnames = true # DNSホスト名を有効化
  tags = {
    Name = "covid19"
  }
}
# ====================
#
# Subnet
#
# ====================

# Public
resource "aws_subnet" "covid19" {
  cidr_block        = "10.0.1.0/24"
  availability_zone = "ap-northeast-1a"
  vpc_id            = aws_vpc.covid19.id
  # trueにするとインスタンスにパブリックIPアドレスを自動的に割り当ててくれる
  map_public_ip_on_launch = true
  tags = {
    Name = "covid19"
  }
}
# Private
resource "aws_subnet" "private-db1" {
  vpc_id            = aws_vpc.covid19.id
  cidr_block        = "10.0.2.0/24"
  availability_zone = "ap-northeast-1a"
  tags = {
    Name = "private-db1"
  }
}
resource "aws_subnet" "private-db2" {
  vpc_id            = aws_vpc.covid19.id
  cidr_block        = "10.0.3.0/24"
  availability_zone = "ap-northeast-1c"
  tags = {
    Name = "private-db2"
  }
}

# ====================
#
# Internet Gateway
#
# ====================
resource "aws_internet_gateway" "covid19" {
  vpc_id = aws_vpc.covid19.id
  tags = {
    Name = "covid19"
  }
}

# ====================
#
# Route Table
#
# ====================
resource "aws_route_table" "covid19" {
  vpc_id = aws_vpc.covid19.id
  tags = {
    Name = "covid19"
  }
}
resource "aws_route" "covid19" {
  gateway_id             = aws_internet_gateway.covid19.id
  route_table_id         = aws_route_table.covid19.id
  destination_cidr_block = "0.0.0.0/0"
}
resource "aws_route_table_association" "covid19" {
  subnet_id      = aws_subnet.covid19.id
  route_table_id = aws_route_table.covid19.id
}
# ====================
#
# Security Group
#
# ====================
resource "aws_security_group" "covid19" {
  vpc_id = aws_vpc.covid19.id
  name   = "covid19"
  tags = {
    Name = "covid19"
  }
}

# インバウンドルール(ssh接続用)
resource "aws_security_group_rule" "in_ssh" {
  security_group_id = aws_security_group.covid19.id
  type              = "ingress"
  cidr_blocks       = ["0.0.0.0/0"]
  from_port         = 22
  to_port           = 22
  protocol          = "tcp"
}

# インバウンドルール(pingコマンド用)
resource "aws_security_group_rule" "in_icmp" {
  security_group_id = aws_security_group.covid19.id
  type              = "ingress"
  cidr_blocks       = ["0.0.0.0/0"]
  from_port         = -1
  to_port           = -1
  protocol          = "icmp"
}

# アウトバウンドルール(全開放)
resource "aws_security_group_rule" "out_all" {
  security_group_id = aws_security_group.covid19.id
  type              = "egress"
  cidr_blocks       = ["0.0.0.0/0"]
  from_port         = 0
  to_port           = 0
  protocol          = "-1"
}